Network install using boot media - No DHCP

[P@docIT]

Is it possible to use boot media to do a network install on a new machine without DHCP? We use static IP and when a machine is on the network with an IP, domain, and SCCM Client I can capture that info and apply it back using the capture network TS. However a new machine will boot right in wpe and obviously does not have IP info yet.

 

Boot media allows you to configure an IP, which works great to get me out any advertised TSs and start the network install however I believe once Windows is applied it changes the network adapter to DHCP. I lose the connection and nothing gets applied after the OS.

 

Is there a way around this without setting up DHCP as it's not a possibility (controlled by another dept).

 

Thanks,

Mike

[P@docIT]

Found this vb script. Works exactly as needed. Thanks again for the help. Hopefully someday I will be proficient enough to give back to this community instead of always just asking for help.

 

Set objWMIService = GetObject ("winmgmts:\\.\root\cimv2")
WQL = "Select * from Win32_NetworkAdapterConfiguration where IPEnabled = TRUE"
Set colNetAdapters = objWMIService.ExecQuery (WQL)
WScript.Echo "Number of adapters is " & colNetAdapters.Count
set objSCCM = CreateObject("Microsoft.SMS.TSEnvironment")
if objSCCM("OSDAdapter0IPAddressList") = "" then
For Each objNetAdapter In colNetAdapters
 if objNetAdapter.DHCPEnabled then
  WScript.Echo "DHCP Enabled"
 else
  WScript.Echo "DHCP Disabled"
  objSCCM("OSDAdapter0EnableDHCP") = false

  if Not IsNull (objNetAdapter.IPAddress) then
strIPAddress = objNetAdapter.IPAddress(0)
WScript.Echo "IP Address:   	" & strIPAddress
objSCCM("OSDAdapter0IPAddressList") = strIPAddress
  end if

  if Not IsNull (objNetAdapter.IPSubnet) then
strIPSubnet = objNetAdapter.IPSubnet(0)
WScript.Echo "IP Subnet:    	" & strIPSubnet
objSCCM("OSDAdapter0SubnetMask") = strIPSubnet
  end if

  if Not IsNull (objNetAdapter.DefaultIPGateway) then
strIPGateway = objNetAdapter.DefaultIPGateway(0)
WScript.Echo "IP Gateway:   	" & strIPGateway
objSCCM("OSDAdapter0Gateways") = strIPGateway
  end if

  if Not IsNull (objNetAdapter.DNSServerSearchOrder) then
strDNSServerSearchOrder = objNetAdapter.DNSServerSearchOrder(0)
WScript.Echo "DNS Server:   	" & strDNSServerSearchOrder
objSCCM("OSDAdapter0DNSServerList") = strDNSServerSearchOrder
  end if
  if Not IsNull (objNetAdapter.MACAddress) then
strMACAddress = objNetAdapter.MACAddress(0)
WScript.Echo "MAC Address:  	" & strMACAddress
  end if

  if Not IsNull (objNetAdapter.DNSDomainSuffixSearchOrder) then
strDNSDomainSuffixSearchOrder = objNetAdapter.DNSDomainSuffixSearchOrder(0)
WScript.Echo "DNS DOMAIN:   	" & strDNSDomainSuffixSearchOrder
  end if

  if Not IsNull (objNetAdapter.WINSPrimaryServer) then
strWins = objNetAdapter.WINSPrimaryServer
objSCCM("OSDAdapter0EnableWINS") = true
if Not IsNull (objNetAdapter.WINSSecondaryServer) then
	strWins = strWins & "," & objNetAdapter.WINSSecondaryServer
end if
WSCript.Echo "WINS Server:  	" & strWins
objSCCM("OSDAdapter0WINSServerList") = strWins
  else
objSCCM("OSDAdapter0EnableWINS") = false
  end if
  objSCCM("OSDAdapterCount") = 1

 end if
Next
End If

[icare]

P@docIT

Can you show me your TS? I need the same and dont know where to put it in the TS (Where do you call the script and restore network setting phase?).

Thanks in advanced

[P@docIT]

I won't be able to post TS until tuesday. However in the mean time you will need to have MDT 2010 installed on your server and a package created for the MDT toolkit (if you don't already). This package can be used to "load" scripts into the TS so they can be called.

[P@docIT]

Here is a screenshot of one of my TS's. You'll see in my Install Operating System group i have a "Use Toolkit Package" this loads MDT for use during the OSD. Right after that I have a TS called "Capture Network Settings" The command line uses cscript and points to my scripts\custom scripts folder in the MDT package.

 

Second screenshot is of my actual MDT package source files. Within that scripts folder I have another folder called custom scripts.

 

Hope that helps.

[AdminSccm]

Hi,

 

I followed your steps and I am capturing the network settings as mentioned but still when my computer boots up, it does not have the specified IP details and is not joined to the domain.

 

Is there a "Appy Network Settings" part needed in the later steps? Or is it something else?

 

Help would be appreciated.

[StarChild]

Hi,

Could you please tell me if this should work with SCCM 2012 SP1 CU4 with MDT 2012 SP1 integrated.

I'm having the same issue.

I need to accomplish exactly the same thing - Server OSD in a datacenter without DHCP.

Our OSD TS looks similar to yours, and we are deploying to an Unknown machine using USB boot media.

On first boot into WinPE, we enter the Network settings to the NIC that we know has a valid drop, and assign a Static IP Address, Subnet Mask, Gateway, DNS, and DNS suffix. Once the step boots beyond WinPE we lose our IP settings.

 

So we would like to try this .vbs script, but :

 

Can you please send me a screenshot of your "Apply Network Settings" --> I would like to two things from such a step:

1) Is the Apply Network Settings being set to "WROKGROUP", or do you have it set to join domain? and,

2) do you also have a LAN0 setting where you need to specify the same static IP address that the .vbs script captures (I'm hoping not)

 

Your help would be much appreciated

[P@docIT]

I know this is few months late but I just saw your post today. Here is a link to the technet post where I got the script from. Hopefully some info there can get you going. I can say 100% that it does work in 2012 as well. Still using it as I don't believe my organization will be moving to DHCP any time soon.

 

https://social.technet.microsoft.com/Forums/systemcenter/en-US/afe6bf8e-e335-4085-8ca0-6beb16b3e322/boot-from-media-and-static-ip-script?forum=configmgrosd

 

To answer your two questions.

 

I use it for domain join and workgroup and I do not add any ip info to lan0, i do use that setting but just make sure that "Register this connection in dns gets checked and to set wins to "Enable NetBIOS over TCP/IP".